Attribute VB_Name = "Module1"
'■　マクロ５００連発＜第２段＞
'
'　郵便番号から住所を取得する
'
'  Copyright(C) 2000 Sunago
'
'  前提：新7桁郵便番号対応キットおよび新 7 桁郵便番号辞書のインストール
'   　　及びアドイン"ZipCode7.xla"への参照設定が必要です。
'
'  使い方：GetZipDecision("103-0027")のように記述すると
'  該当する住所を取得することができます。
'
Option Explicit

Declare Function wu_GetZipDecision Lib "MSYUBIN7" _
        Alias "GetZipDecision" _
        (ByVal ZipCode$, _
         ByVal szKen$, _
         ByVal szCty1$, _
         ByVal szCty2$, _
         ByVal szTwn$, _
         ByVal szTwnExt$) As Integer

'/* GetZipDecisionカバー関数 */

Public Function GetZipDecision(sYubin As String) As String
Dim szKen As String * 255
Dim szCty1 As String * 255
Dim szCty2 As String * 255
Dim szTwn As String * 255
Dim szTwnExt As String * 255
Dim sKen As String
Dim sCty1 As String
Dim sCty2 As String
Dim sTwn As String
Dim sTwnExt As String
Dim iret As Integer

    fnStartYubin7
    iret = wu_GetZipDecision(sYubin, szKen, szCty1, szCty2, szTwn, szTwnExt)
    sKen = Left(szKen, InStr(szKen, vbNullChar) - 1)
    sCty1 = Left(szCty1, InStr(szCty1, vbNullChar) - 1)
    sCty2 = Left(szCty2, InStr(szCty2, vbNullChar) - 1)
    sTwn = Left(szTwn, InStr(szTwn, vbNullChar) - 1)
    sTwnExt = Left(szTwnExt, InStr(szTwnExt, vbNullChar) - 1)
    GetZipDecision = sKen & sCty1 & sCty2 & sTwn & sTwnExt

End Function

'/* 使い方の例 */

Sub Macro1()
Dim sYubin As String

    sYubin = "103-0027"
    MsgBox "郵便番号" & sYubin & vbCr & _
            GetZipDecision(sYubin)
End Sub