'=========================================================================================
' 446 ユーザーフォームの色を変える
'-----------------------------------------------------------------------------------------
'【ヒント】
' このマクロは、おためし機能の動作用のコードを含んでいます。（概ね下半分）
' ★★★の行またはサブプロシージャーが、タイトル機能に関係するコードです。（概ね上半分）
' UserForm1にもコードがあり、標準モジュールのコードと連係して動作します


'=========================================================================================
' ◆標準モジュールのコード◆
'-----------------------------------------------------------------------------------------
Option Explicit
Public 指示 As Integer                      '★★★ Initializeイベントの動作指示
Dim タイトル As String
Dim スタイル As Long
Dim メッセージ As String
Dim 応答 As Variant
'=========================================================================================
Private Sub ユーザーフォームを表示する()        '★★★
    For 指示 = 1 To 6
        UserForm1.Show
    Next
End Sub
'=========================================================================================



'-----------------------------------------------------------------------------------------
Sub おためしマクロ()
    おためしメッセージを表示する
    ユーザーフォームを表示する                  '★★★
End Sub
'-----------------------------------------------------------------------------------------
Private Sub おためしメッセージを表示する()
    Worksheets("Title").Select
    Range("P17").Select                        'カーソルを定位置へ移動する
    タイトル = "500連発 第2弾 サンプルマクロ"
    スタイル = 64                               'vbInformation
    メッセージ = "ユーザーフォームを表示して、色を変えます。" & Chr(13) & Chr(13) & _
                "表示された説明内容を確認したら、ユーザーフォームの" & Chr(13) & Chr(13) & _
                "　　　　［OK］ボタンをクリックして進んでください。"
    応答 = MsgBox(メッセージ, スタイル, タイトル)
End Sub
'-----------------------------------------------------------------------------------------
Sub Auto_Close()
    Application.DisplayAlerts = False           '閉じる際に確認メッセージを出さない
    ActiveWorkbook.Close                        '現在開いているブックを閉じる
End Sub
'-----------------------------------------------------------------------------------------



'=========================================================================================
' ◆UserForm1のコード◆
'-----------------------------------------------------------------------------------------
Private Sub UserForm_Initialize()               '★★★
    Select Case 指示
        Case 1
            Label1.Caption = "(1) デフォルト・カラーです"
        Case 2
            Label1.Caption = "(2) ユーザーフォームの背景色を変えました"
            BackColor = RGB(255, 255, 0)        'RGB関数は解説シート参照
        Case 3
            Label1.Caption = "(3) ユーザーフォームの境界線色を変えました"
            BorderColor = RGB(255, 0, 0)
        Case 4
            Label1.Caption = "(4) ラベルの背景色を変えました"
            Label1.BackColor = RGB(255, 255, 0)
        Case 5
            Label1.Caption = "(5) ラベルの文字の色を変えました"
            Label1.ForeColor = RGB(255, 0, 0)
        Case Else
            Label1.Caption = "(2)から(5)をいっせいに変えました"
            BackColor = RGB(255, 255, 0)
            BorderColor = RGB(255, 0, 0)
            Label1.BackColor = RGB(255, 255, 0)
            Label1.ForeColor = RGB(255, 0, 0)
            CommandButton1.BackColor = RGB(0, 255, 0)
            CommandButton1.ForeColor = RGB(255, 0, 0)
    End Select
End Sub
'-----------------------------------------------------------------------------------------
Private Sub CommandButton1_Click()              '★★★
    Unload Me                                   'ユーザーフォームを閉じる
End Sub
'=========================================================================================