'=========================================================================================
' 415 コマンドボタンの色と表示を変える
'-----------------------------------------------------------------------------------------
'【ヒント】
' このマクロは、おためし機能の動作用のコードを含んでいます。（概ね下半分）
' ★★★の行またはサブプロシージャーが、タイトル機能に関係するコードです。（概ね上半分）
' UserForm1にもコードがあり、標準モジュールのコードと連係して動作します


'=========================================================================================
' ◆標準モジュールのコード◆
'-----------------------------------------------------------------------------------------
Option Explicit
Public 指示 As Integer                      'Initializeイベントの動作指示
Dim タイトル As String
Dim スタイル As Long
Dim メッセージ As String
Dim 応答 As Variant
'=========================================================================================
Sub コマンドボタンの色と表示を変える()
    For 指示 = 1 To 8
        UserForm1.Show
    Next
End Sub
'=========================================================================================



'-----------------------------------------------------------------------------------------
Sub おためしマクロ()
    おためしメッセージを表示する
    コマンドボタンの色と表示を変える            '★★★
End Sub
'-----------------------------------------------------------------------------------------
Private Sub おためしメッセージを表示する()
    Worksheets("Title").Select
    Range("P17").Select                        'カーソルを定位置へ移動する
    タイトル = "500連発 第2弾 サンプルマクロ"
    スタイル = 64                               'vbInformation
    メッセージ = "ユーザーフォームを表示して、コマンドボタンの色と表示を変えます。" & Chr(13) & Chr(13) & _
                "表示された説明内容を確認したら、ユーザーフォームの" & Chr(13) & Chr(13) & _
                "　　　　［OK］ボタンをクリックして進んでください。"
    応答 = MsgBox(メッセージ, スタイル, タイトル)
End Sub
'-----------------------------------------------------------------------------------------
Sub Auto_Close()
    Application.DisplayAlerts = False           '閉じる際に確認メッセージを出さない
    ActiveWorkbook.Close                        '現在開いているブックを閉じる
End Sub
'-----------------------------------------------------------------------------------------



'=========================================================================================
' ◆UserForm1のコード◆
'-----------------------------------------------------------------------------------------
Private Sub UserForm_Initialize()
    Select Case 指示
        Case 1
            Label1.Caption = "(1) コマンドボタンのキャプションは「OK」です"
            CommandButton1.Caption = "OK"
        Case 2
            Label1.Caption = "(2) コマンドボタンのキャプションを「はい」に変えました"
            CommandButton1.Caption = "はい"              '
        Case 3
            Label1.Caption = "(3) コントロールチップテキストは未設定です"
            CommandButton1.ControlTipText = ""
        Case 4
            Label1.Caption = "(4) コントロールチップテキストを設定しました"
            CommandButton1.ControlTipText = "よく確かめてからクリックしてネ"
        Case 5
            Label1.Caption = "(5) コマンドボタンは、デフォルト・カラーです"
        Case 6
            Label1.Caption = "(6) コマンドボタンの背景色を変えました"
            CommandButton1.BackColor = RGB(0, 255, 0)
        Case 7
            Label1.Caption = "(7) コマンドボタンの文字の色を変えました"
            CommandButton1.ForeColor = RGB(255, 0, 0)
        Case Else
            Label1.Caption = "(8) コマンドボタンの背景色と文字の色を、同時に変えました"
            CommandButton1.BackColor = RGB(0, 255, 0)
            CommandButton1.ForeColor = RGB(255, 0, 0)
    End Select
End Sub
'-----------------------------------------------------------------------------------------
Private Sub CommandButton1_Click()
    Unload Me                                   'ユーザーフォームを閉じる
End Sub
'=========================================================================================