Attribute VB_Name = "Module1"
'■　マクロ５００連発＜第２段＞
'
'　独自に追加したメニュー項目の存在を確認する
'
'  Copyright(C) 2000 Sunago
'
'  　独自に追加したメニュー項目の存在を確認するために
'  Tagプロパティを利用します。Tagプロパティは独自メニュー
'  を追加する時点で設定しておきます。
'
'  ※サンプルの動作を確認するには、macTestMenuAddを実行して、
'  　テスト用のメニュー項目を追加しておきます。
'
Option Explicit

Const CMNUBAR = "Worksheet Menu Bar"
Const CMNUEXT = "テスト"

Sub Macro1()
Dim myCBarCtrl As CommandBarControl

    With Application.CommandBars(CMNUBAR)
        Set myCBarCtrl = .FindControl(Tag:=CMNUEXT)
        If myCBarCtrl Is Nothing Then
            MsgBox "MenuControl Not Found!"
          Else
            MsgBox "MenuControl Found!"
        End If
        Set myCBarCtrl = Nothing
    End With
End Sub

Sub macTestMenuAdd()
'/* テスト用の独自メニューを作成する */
Dim myCBarCtrl As CommandBarControl

    With Application.CommandBars(CMNUBAR)
        Set myCBarCtrl = .Controls.Add(Type:=msoControlButton)
        With myCBarCtrl
            .Style = msoButtonCaption
            .Caption = CMNUEXT
            .Tag = CMNUEXT          '検索時の識別として設定する
        End With
        Set myCBarCtrl = Nothing
    End With
End Sub

Sub macTestMenuReset()
'/* CommandBars(1)の状態を実行前の状態に戻す */
Dim myCBarCtrl As CommandBarControl

    With Application.CommandBars(CMNUBAR)
    '指定タグのコントロールのみを削除する
        Set myCBarCtrl = .FindControl(Tag:=CMNUEXT)
        If Not myCBarCtrl Is Nothing Then
            myCBarCtrl.Delete
        End If
        Set myCBarCtrl = Nothing
    End With
End Sub